home *** CD-ROM | disk | FTP | other *** search
/ Aminet 2 / Aminet AMIGA CDROM (1994)(Walnut Creek)[Feb 1994][W.O. 44790-1].iso / Aminet / dev / c / RConfig.lha / RConfig_v1.1 / rlib / rlib_stkchk.c < prev    next >
Encoding:
C/C++ Source or Header  |  1992-09-13  |  4.8 KB  |  169 lines
  1. /*
  2.  * rlib.c   v1.3
  3.  * ~~~~~~
  4.  *   Copyright (C) 1986,1987 by Manx Software Systems, Inc.
  5.  *   Copyright (C) 1992 by Anthon Pang, Omni Communications Products.
  6.  *
  7.  *   Replacement library for:
  8.  *     - stkchk.a68
  9.  */
  10.  
  11. /*
  12.  * stkchk()
  13.  */
  14. #ifdef __STKCHK_REPLACE
  15.  
  16. #if defined(__BETTER_STKCHK) && defined(__DYNASTACK_STKCHK)
  17. #error "Conflicting stkchk() flags--{BETTER, DYNASTACK}"
  18. #endif
  19.  
  20. #if defined(__BETTER_STKCHK) && defined(__DYNASTACK_STKCHK)
  21. #error "Missing stkchk() flags--{BETTER, DYNASTACK}"
  22. #endif
  23.  
  24. #asm
  25.     cseg
  26.  
  27.     public  __stkbase
  28.     public  __stkover
  29.     public  _malloc
  30.     public  __savsp
  31.  
  32. ; constants defined externally...examples
  33. ;   STKCHK_MIN_STACK    SET 2768
  34. ;   STKCHK_STACK_SIZE   SET 8192
  35. ;   STKCHK_CONTEXT_SIZE SET  128
  36.  
  37. ; __stkchk
  38. ;
  39. ;   - check if stack's magic cookie munged
  40. ;   - check if sufficent stack for stack frame
  41. ;   - allocate additional stack space if required (and enabled)
  42. ; 
  43. ; scratch registers: d0/a0-a1
  44.  
  45.     public  __stkchk
  46. __stkchk:
  47.     move.l  __stkbase,a0
  48.  
  49.     cmp.l   #'MANX',(a0)                ; check magic cookie
  50.     bne.s   crunch                      ; branch if stack munged
  51.  
  52.     add.w   #%%STKCHK_MIN_STACK,a0      ; check stack space available
  53.     neg.w   d0
  54.     add.w   d0,a0
  55.     cmp.l   a7,a0
  56.  
  57. #endasm
  58.  
  59. #ifdef __BETTER_STKCHK
  60. #asm
  61.     bge.s   crunch                      ; branch if stack would overflow
  62. #endasm
  63. #endif
  64.  
  65. #ifdef __DYNASTACK_STKCHK
  66. #asm
  67.     blt.s   captain                     ; branch if there's enough stack
  68.  
  69.     ext.l   d0                          ; alloc mem for size of stack frame...
  70.     add.l   #%%STKCHK_STACK_SIZE,d0     ; ...and add a bit for future use
  71.     move.l  d0,-(a7)
  72.     jsr     _malloc#
  73.  
  74.     tst.l   d0                          ; check ptr
  75.     beq.s   crunch                      ; branch if unable to alloc memory
  76.  
  77.     move.l  d0,a0                       ; d0 = a0 = new stkbase
  78.     move.l  #'MANX',(a0)                ; store magic cookie
  79.     move.l  (a7)+,a0                    ; pop size
  80.     add.l   d0,a0                       ; get top of new stack
  81.  
  82.     move.l  __stkbase,-(a0)             ; save old stkbase on extension stack
  83.     move.l  a7,-(a0)                    ; save the current stack pointer
  84.     move.l  d0,__stkbase                ; store new stkbase
  85.  
  86.     move.l  __savsp,a1                  ; get top
  87.     cmp.l   a1,a7
  88.     bge.s   copyfullcontext             ; ignore the case where the extension
  89.                                         ; stack is higher than the orig. stack
  90.  
  91.                                         ; at this point: a1 > a7
  92.     sub.l   a7,a1                       ; get difference of top & current sp
  93.                                         ; this represents amt of valid context
  94.                                         ; plus 8
  95.  
  96.     cmp.l   #%%STKCHK_CONTEXT_SIZE+8,a1 ; compare difference with context size
  97.     bge.s   copyfullcontext             ; if a1 greater, a full context is
  98.                                         ; available
  99.  
  100. copypartialcontext:     ; but pad it out to 128 bytes
  101.     sub.l   #%%STKCHK_CONTEXT_SIZE,a0
  102.     add.l   a1,a0                       ; skip unavailable context
  103.  
  104.     move.l  a1,d0                       ; number of bytes to copy
  105.                                         ; (this may not work out to
  106.                                         ; an even number of longs)
  107.  
  108.     lea     8(a7,d0),a1
  109.  
  110.     lsr.l   #1,d0                       ; number of words to copy
  111.     subq.l  #1,d0                       ; number of words to copy - 1
  112.  
  113.     bra.s   copynextword
  114.  
  115. copyfullcontext:
  116.     moveq   #(%%STKCHK_CONTEXT_SIZE-2)/2,d0 ; copy 'small' context from current...
  117.     lea     %%STKCHK_CONTEXT_SIZE+8(a7),a1  ; ...stack to extension stack
  118.  
  119. copynextword:
  120.     move.w  -(a1),-(a0)
  121.     dbra    d0,copynextword
  122.  
  123. finishedcopy:
  124.     move.l  (a7),d0                     ; get return address (caller of stkchk)
  125.  
  126.     move.l  a0,a7                       ; swap stacks
  127.  
  128.     pea     __stkfree#                  ; this is the clean up routine; called
  129.                                         ; when the calling 'proc' ends
  130.  
  131.     move.l  d0,-(a7)                    ; push addr of where to resume
  132. #endasm
  133. #endif
  134.  
  135. #asm
  136. captain:
  137.     rts
  138.  
  139. crunch:
  140.     jmp     __stkover#
  141. #endasm
  142.  
  143. #ifdef __DYNASTACK_STKCHK
  144. #asm
  145.     public  __stkfree
  146.     public  _free
  147.  
  148. ;
  149. ; __stkfree - free a dynamically allocated stack (as stack unwinds)
  150. ;   scratch registers: a0
  151. ;
  152. __stkfree:
  153.     lea     %%STKCHK_CONTEXT_SIZE(a7),a7    ; skip past context (note: no copyback)
  154.  
  155.     move.l  __stkbase,a0                ; temp = current stkbase
  156.     move.l  4(a7),__stkbase             ; restore old stkbase
  157.  
  158.     move.l  (a7),a7                     ; unwind stack
  159.  
  160.     move.l  a0,-(a7)
  161.     jsr     _free                       ; free empty stack
  162.     addq.l  #8,a7                       ; clean up stack after malloc() & free()
  163.  
  164.     rts
  165.  
  166. #endasm
  167. #endif
  168. #endif /* __STKCHK_REPLACE */
  169.